通达信副图指标-市盈率加强版
昨天的动态市盈率公式有点问题，不应该使用 FINANCE(33) 函数，昨天留言有说，但是担心很多朋友没有看到，所以今天把修改后的公式重新发布一下。
滚动市盈率指标公式不变，只修改了动态市盈率指标公式。
大家有公式方面的问题请在留言区留言，不要在公众号直接发私信啦！
如果公式有什么问题我也会留言置顶。
五一假期转眼就只剩下一天了，大家休息的可好。明天大A就要开盘了，惊不惊喜，意不意外
这个五一我也出去瞎晃了两天，所以除了1号给大家推了一篇公式合集，后面几天都没更新了。
不过节前在滚动市盈率那篇说了五一会研究一下市盈率的公式，这个还是没忘记的，今天就给大家分享一下市盈率加强版。
再强调一下，后面正文里面就不每篇都提醒了，大家最好养成习惯，每天先更新一下财务数据再看公式
提醒：本公式使用了财务函数，需要先下载【专业财务数据】
下载流程：【系统】-【专业财务数据】-【开始下载】
前面不少朋友建议加上动态市盈率，这次我就把滚动市盈率和动态市盈率的公式都写了一下，分了两个指标，大家使用的时候记得要建两个公式，不要混到一起了。
其实，如果只是仅仅把滚动市盈率和动态市盈率放在一个副图也可以，但是加了其他画线的数据一起，线就太多了，比较乱，这也是为什么我要分两个副图指标。
先上几张效果图
日线周期
周线周期
月线周期
滚动市盈率(TTM)指标公式:
==============================================
净利润TTM := FINVALUE(276), NODRAW; {近一年净利润}
总市值 := FINVALUE(238)*C, NODRAW;
市盈率TTM : IF(净利润TTM>0, 总市值/净利润TTM, 0), COLORYELLOW, LINETHICK2;
{周期数}
PCOUNT := IF(PERIOD = 7, 120, IF(PERIOD = 6, 500, 2500));
MCOUNT := IF(TOTALBARSCOUNT>PCOUNT,PCOUNT,TOTALBARSCOUNT);
近10年最大 : HHV(市盈率TTM, MCOUNT), COLORYELLOW, LINETHICK1;
近10年最小 : IF(LLV(市盈率TTM, MCOUNT)<0, 0, LLV(市盈率TTM, MCOUNT )), COLORYELLOW, LINETHICK1;
当前平均值 := SUM(IF(市盈率TTM<0,0,市盈率TTM), MCOUNT)/MCOUNT;
近10年平均 : DRAWLINE(CURRBARSCOUNT=MCOUNT, CONST(当前平均值), CURRBARSCOUNT=1, 当前平均值, 3), COLORGREEN, DOTLINE;
近10年百分位 : (市盈率TTM - 近10年最小)/(近10年最大 - 近10年最小), NODRAW;
==============================================
动态市盈率指标公式:
==============================================
报告期 := FINVALUE(0) - INTPART(FINVALUE(0)/10000)*10000, NODRAW;
每股收益 : IF(报告期=331, FINVALUE(1)*4, IF(报告期=630, FINVALUE(1)*2, IF(报告期=930, FINVALUE(1)*4/3, FINVALUE(1)))), NODRAW;
动态市盈率 : IF(C/每股收益<0, 0, C/每股收益), COLORRED, LINETHICK2;
{周期数}
PCOUNT := IF(PERIOD = 7, 120, IF(PERIOD = 6, 500, 2500));
MCOUNT := IF(TOTALBARSCOUNT>PCOUNT,PCOUNT,TOTALBARSCOUNT);
近10年最大 : HHV(动态市盈率, MCOUNT), COLORRED, LINETHICK1;
近10年最小 : IF(LLV(动态市盈率, MCOUNT)<0, 0, LLV(动态市盈率, MCOUNT)), COLORRED, LINETHICK1;
当前平均值 := SUM(IF(动态市盈率<0,0,动态市盈率), MCOUNT)/MCOUNT;
近10年平均 : DRAWLINE(CURRBARSCOUNT=MCOUNT, CONST(当前平均值), CURRBARSCOUNT=1, 当前平均值, 3), COLORGREEN, DOTLINE;
近10年百分位 : (动态市盈率 - 近10年最小)/(近10年最大 - 近10年最小), NODRAW;
行业市盈率 : HYSYL, NODRAW;
==============================================
简单解释一下：
计算最大、最小、平均值我使用的是近10年的数据。因为历史太久远的，不具备参考性了。大家要是10年还嫌长的，可以自己修改周期数 PCOUNT。
这两个公式周期暂时都只支持日线、周线、月线，想加其他周期的可以自己判断一下PERIOD 的值，然后赋值给 PCOUNT。
近10年平均，因为日线、周线、月线计算的值是不一样的，是因为这个平均值是用周期最后一日的市盈率相加除以周期数计算出来的，所以不同周期计算会有偏差。
日线是每天的收盘价数据计算平均值，周线是每周收盘价数据计算的，月线是每月的收盘价计算的。
这里，计算最精准的应该是日线。
本来还想加一个当前价格分别对应未来两年的市盈率，但是预测未来两年的净利润的数据暂时还没搞定，所以就没加上了。后面我研究出来了会分享出来的。